MSE has a tag, but I'm now sure there's a full listing of all the questions that are identified as bugs by the community convention of putting:

Bug introduced in `` [resolved in ``]


At the top of the question.

Is there an easy to find page with all of them? If not, how can we build one?

  • I do not know about "resolved" being the community convention: Looking up "and fixed" vs. "and resolved" comes up 466 to 6 on Mathematica.SE - seems to "fixed" has won out by now. ;-) – gwr Mar 11 at 13:13
  • This to me seems to be the community convention btw. – gwr Mar 11 at 13:17
  • 1
    @gwr my code actually looks for both – b3m2a1 Mar 11 at 15:23

I compiled a dataset of these which I can quickly and easily update on request. It currently goes up to to Jan 2018.

bugsQs =
  CloudImport[
   "user:b3m2a1.datasets/stack_exchange_data/questions/\
mmaBugsWithVersions.mx"];
bugsGroups =
  KeySortBy[
    ToExpression@
      PadRight[
       Flatten@
        List@Replace[StringSplit[#,  "."], {{"Unknown"} -> {"0"}}],
       5,
       "0"
       ] &
    ]@
   KeyMap[Replace[None -> "Unknown"]]@
    bugsQs[
     GroupBy["Introduced"]
     ];
bugsLinks =
  KeyValueMap[
   "### Version " <> # <> "\n\n" <>
     StringRiffle[
      Map[
       TemplateApply[
         "* [`title`](`link`)",
         #
         ] &,
       #2
       ],
      "\n"
      ] &,
   Normal@bugsGroups
   ];
bugsCol =
  Column[
   KeyValueMap[
    Column[{
       Style["Version " <> #, "Section"],
       Row@{
         Column[
          Map[
           Hyperlink[#title, #link] &,
           #2
           ]
          ]
         }
       }
      ] &,
    Normal@bugsGroups
    ]
   ];

This builds out both Markdown and a column with all the bugs.

I then deployed this to a static page:

pageTemplate = 
  "1:eJyVVMFy0zAQ7YX/2OqSC4obhgMDURnIhJl2OJR0OvTADFWsdawgy0ba2LTfyscgO45jJ+20+CKt9Hb19J5Xp8t8cf331cnJNKXMgJF2JRhadv7jbPIGYJqiVO08RKTJYBcCfM9N4mQGM5NvVIeKhrBphiQhTqXzSIJtKOHv2MFuSlRw/L3RpWC3/OYTn+VZIUkvDTKIc0toQ+rFXKBa4WGylRkKVmqsitxRD19pRalQWOoYeRO8Bm01aWm4j6VBMdnXOhynp5zDzKEkVFBpSrvbfg0ibeQKgfMmu8sw2v6C1GEiRvWF/PsoqqpqXG3z4lqkcZxnUeTQR5RiFobY+6hKNeE403YcohHQfRHuQ/iH6l0GDo1gnu4N+hSRhpRbn6LOqHZhmat7iI30XozqOVeYyI2hkDYasO7YK122CcwHPrxysijQsZ7fT2G4tnaH3KP71R+Pj/GN6p9xpS0UtcStlzupe8CailaCtQi241XHUgc60M14FgZ2fsjlmN3whvv84FctXW0JN5i0FtzdHfPfNkAo8uxpj6GeV6ufuxXryIe+Vk8B+5jBL9z89LlDuJSlvI6dLmi3J/77GzCpK18ZGYdukkHKFAGtgjxppiqPN1nts8+buPbeg8mlgkR6GhKe+oZXv0/Wge12tW9zKR0s5t9uLhbzy+ufV4v5l4tbEMBe3Jzsw17IbfkjEqGt0AnWDOwJSuBdLF5+6tpHwaTmPVj7j6WYjN+ejSeEy3JJsbUPZsXOj/js3oG615vF8CSEF72Z/gNlnLHi";

KeyChainConnect["DatasetsAccount"];
CloudExport[
 TemplateApply[
  pageTemplate,
  ExportString[bugsCol, "HTMLFragment"]
  ],
 "HTML",
 "stack_exchange_data/notebooks/bugList.html",
 Permissions -> "Public"
 ]

So you can look at the bugs listing here.

  • I am not sure it makes sense to list tyem in separate answers. Would be more informative to show more examples of querying maybe – Kuba Jan 14 at 8:43
  • @Kuba too much text to put in one unfortunately – b3m2a1 Jan 14 at 8:43
  • I meant to not post them at all :) – Kuba Jan 14 at 9:57
  • 1
    @Kuba ah okay. I thought having a listing on the site might be helpful. I'll just link to a cloud page where I aggregate them instead. – b3m2a1 Jan 15 at 8:16
  • I checked your list and it looks like the bug I discovered isn't on it (why? my question had the tag), but it is still there and hasn't got resolved. – polfosol Mar 11 at 12:54
  • @polfosol because I need to rerun the aggregation. It's not auto-updating. – b3m2a1 Mar 11 at 15:22

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .