12

One way we can promote this site is to create a community promotion ad to be shown on other SE sites. Each graduated SE site has a meta question where people can submit these ads (math, physics, stats), and if they receive enough upvotes they will be automatically shown by the system.

If we are going to be advertising Mathematica.SE in this way, I think it would be useful to coordinate it so that we have one designated ad to represent the site, and then submit it to the community promotion ad questions on all related sites. So I'm posting this meta question to collect ideas. After a few days we can take the top voted submission and "distribute" it. (As a side effect, this could get people brainstorming about good logo ideas)

When an actual community ad is submitted, it is required to be in the form

[![Tagline to show on mouseover][1]][2]

   [1]: http://image-url
   [2]: http://clickthrough-url 

The image must be exactly 220x250 pixels, in GIF or PNG format (not animated), and hosted on SE's Imgur account. I don't think it's strictly necessary for answers to this question to follow that format, but it would be convenient. Answers posted here should definitely include the three required elements: image, tagline, and URL.


Note: the ads have now been posted!

They will be shown if they have at least 6 upvotes. Please see here:

  • So if got it right, this is not about showing ads on Mma.SE, but about advertising Mma.SE on graduated related sites such as Math.SE, Physics.SE, StackOverflow. We need to make an ad, and post it in those sites' ad-discussion. Is this correct? – Szabolcs Jan 27 '12 at 12:16
  • Yes, exactly. We don't get to show ads on Mma.SE until (some time after) this site graduates. – David Z Jan 27 '12 at 18:12
  • @DavidZaslavsky Okay, I see what you are trying to do. I missed that you were posting these in other meta threads. If they get voted up, they are perfectly appropriate. Carry on. – Robert Cartaino Jan 27 '12 at 22:09
  • @DavidZaslavsky we (finally) have a pretty good looking one below. Thoughts? – rcollyer May 23 '12 at 14:24
  • I have also linked the new version (with new logo) on my own site – Verbeia Aug 1 '12 at 12:18
13

This is just a tweak on Szabolcs' ad, with a different slogan to make the case for why someone should join (we're fun! Just look at some of the most upvoted questions!)

using "BeachColors"

BeachColors scheme

Also using "BeachColors" but reversing the ordering of the colours and removing the extremes:

reversed BeachColors scheme

colour5[s_: "SouthwestColors"] :=  Polygon[v_] /; 
 Length[v] == 4 :> {ColorData[s, 
  Rescale[(6 - 7 Norm[PolygonCentroid[v]])/4, {0, 1}, {0.2,  0.8}]], Polygon[v]}

Here's one with a bit more contrast, in response to Szabolcs's comment:

reversed BeachColors scheme with contrast

Now using the following, which takes the brown out:

colour5[s_: "SouthwestColors"] := Polygon[v_] /; 
  Length[v] == 4 :> {ColorData[s, 
  Rescale[(6 - 7 Norm[PolygonCentroid[v], 2])/4, {0, 1}, {0.1, 1}]], Polygon[v]}

We could do several versions with different colours. Consider:

colour5[s_: "SouthwestColors", {a_, b_}] /; 0 <= a <= 1 && 0 <= b <= 1 :=
   Polygon[v_] /; Length[v] == 4 :>
   {ColorData[s, Rescale[(6 - 7 Norm[PolygonCentroid[v], 2])/4, {0, 1}, {a, b}]],
    Polygon[v]}

And to explore:

Manipulate[
 Graphics[p /. triangulate /. moretriangles /. shrink /. shrink /. 
      colour3[] /. colour5[i, {min, max}] /. curve /. bolics], {i, 
  ColorData["Gradients"]}, {min, 0, 1}, {max, 0, 1}]

Here is colour5["SunsetColors", {0.256, 0.844}]:

SunsetColors version

  • Yes, I think we should use your slogan! I like BeachColors too, though a bit more contrast in the second one would be nice – Szabolcs May 23 '12 at 10:49
  • I split off the logo size and position in the code as separate variables to make them easier to tune (otherwise it takes some digging to find the right number to modify) – Szabolcs May 23 '12 at 10:51
  • 4
    I think I like the last one. It just glows... :) – J. M. is computer-less May 23 '12 at 12:11
  • Now, if we could make them cdf scripts and have a shifting color scheme. :) – rcollyer May 23 '12 at 13:53
  • @rcollyer well, they do allow GIFs and GIFs can be animated ;-) I don't think they'd be happy about an animated GIF though ... – Szabolcs May 23 '12 at 14:20
  • It just needs a tag-line to conform to the community promotion ad standards (see the question). – rcollyer May 23 '12 at 14:21
  • @Szabolcs no they wouldn't. But, it was a thought! – rcollyer May 23 '12 at 14:22
  • @rcollyer You can see the tagline in my post, I just wrote: "Mathematica at StackExchange". It's supposed to show up when hovering the ad (as a tooltip), but I can't see it in Firefox for some reason (neither in the posts, nor on the actual ads that appear on the site). I think we can use the same tagline that she put on the image. – Szabolcs May 23 '12 at 14:25
  • 2
    @Szabolcs: I'm fine with posting the ad on meta.math.SE if we all come to an agreement, though as I said, I prefer Verbeia's last one to my initial proposal... – J. M. is computer-less May 23 '12 at 14:40
  • 3
    I like this :-) If people are in agreement I can go ahead and put the last one on Physics meta (although I wouldn't mind of someone else does so, because that way I'd get to vote for it). – David Z May 23 '12 at 15:25
  • 2
    These are great, I love them all! The last one is particularly reminiscent of Mathematica 6's spikey, and the second one is a bit like Mathematica 5's. They all clearly say "Mathematica", but without cribbing too much from the official symbols. Perfect! – Oleksandr R. May 24 '12 at 0:37
  • 2
    @J.M. I think it's okay to go ahead and post the ad now. EVeryone seems to like it. We can always change it later to a better version if someone makes one, or rotate through several versions (whuber's idea). – Szabolcs May 24 '12 at 7:12
  • 1
    @DavidZaslavsky I think it's okay to go ahead and post the ad now. EVeryone seems to like it. We can always change it later to a better version if someone makes one, or rotate through several versions (whuber's idea). – Szabolcs May 24 '12 at 7:12
  • 2
    OK, done. meta.physics.stackexchange.com/a/1314/124 – David Z May 24 '12 at 7:36
  • 1
    @Szabolcs: It is finished. – J. M. is computer-less May 24 '12 at 7:48
7

NOTE: I'm leaving this post here because it has the code, but I myself prefer @Verbeia's last version.


The ad!

Pieced together from existing bits, here's one possibility. This is a start.

Mathematica at StackExchange

Please upvote if you think it's ready to be used. Please do comment if you think something needs to be changed first (I'll update the post with the changes). Or even better: make the changes and post another variation. (Note that everything I used here is borrowed from other posts.)

The usual "Help this community grow" line (that's used by SE in their in-house ads) can seem a little boring, but I think it immediately makes it clear that this is not an advertisement for Mathematica the program, but for a Mathematica QA site.


Posting the ad on graduated SE sites

I am going to post it on Physics.SE, Math.SE and CrossValidated if it gets enough upvotes here (say, clearly more than the parent question). Instead I propose that the people who post the upvoted ads should be high rep users on the respective sites, so the ads are received better. @J.M. has high rep on Math.SE, @DavidZaslavsky is a mod on Physics and @whuber is a mod on CrossValidated. Are you willing to post these yourself, when the ads are ready (please reply in comments)? Finally what do you think about advertising on Theoretical CS as well?


Full code

Full code follows (copy, paste and evaluate). I chose to make it fully in Mathematica so everyone on this site can easily contribute and can easily change things. Upscaling and doing an ImageResize ensures that everything has a uniform, platform-independent smooth look and that the polygons in the logo are joined without white "cracks" inbetween them. Note that for now I used the font Candara which might not be present on your system (if you have Windows or Office (even on Mac), it's very likely you have it already).

p = Polygon[
   Table[N[{Cos[t], Sin[t]}], {t, \[Pi]/10, 2 \[Pi], (2 \[Pi])/5}]];

triangulate = 
  Polygon[v_] :> (Polygon[Append[#, Mean[v]]] & /@ 
     Partition[v, 2, 1, {1, 1}]);

moretriangles = 
  Polygon[{a_, b_, c_}] :> 
   With[{ab = (a + b)/2, bc = (b + c)/2, 
     ca = (c + a)/2}, {Polygon[{a, ab, ca}], Polygon[{ab, b, bc}], 
     Polygon[{c, ca, ab}], Polygon[{c, ab, bc}]}];

shrink = Polygon[{a_, b_, c_}] :> 
   With[{aa = (6 a + b + c)/8, bb = (a + 6 b + c)/8, 
     cc = (a + b + 6 c)/8}, {Polygon[{a, b, bb, aa}], 
     Polygon[{b, c, cc, bb}], Polygon[{c, a, aa, cc}], 
     Polygon[{aa, bb, cc}]}];

curve = Polygon[v_] :> 
   FilledCurve[
    Line[Map[{10 - #, #}/10 &, Range[0, 10]].#] & /@ 
     Partition[v, 2, 1, {1, 1}]];

f[r_] := Re[(ArcSin[2 r - 1] + \[Pi]/2)/2];

bolics = v : {_?NumberQ, _} :> f[Norm[v]] v;

colour3[s_: LightGray] := q : Polygon[{_, _, _}] :> {s, q}

PolygonCentroid[pts_?MatrixQ] := 
 With[{dif = Map[Det, Partition[pts, 2, 1, {1, 1}]]}, 
  ListConvolve[{{1, 1}}, Transpose[pts], {-1, -1}].dif/(3 Total[dif])]

colour4[s_: "SouthwestColors"] := 
 Polygon[v_] /; 
   Length[v] == 4 :> {ColorData[
    s, (7 Norm[PolygonCentroid[v], 2] - 2)/4], Polygon[v]}

logo = Graphics[
  p /. triangulate /. moretriangles /. shrink /. shrink /. 
      colour3[] /. colour4[] /. curve /. bolics]

logosize = 5;
logoposition = 11.5;

ad = Show[logo, Axes -> False, Frame -> True, FrameTicks -> False, 
   PlotRange -> 1/logosize {{-11, 11}, {0, 25} - logoposition}, 
   Epilog -> {Text[Style["\!\(\*
StyleBox[\"Mathematica\",\nFontSlant->\"Italic\"]\).SE", 
       FontWeight -> Bold, FontSize -> Scaled[1/10], 
       FontFamily -> "Candara"], Scaled[{0.5, 0.09}]],
     Text[
      Style["Help this community grow!", 
       FontSize -> Scaled[1/(10 Sqrt[2])], FontFamily -> "Candara", 
       FontColor -> Gray], Scaled[{0.5, 0.89}]]}];


adimg = ImageResize[
  Rasterize[ad, "Image", ImageResolution -> 3 72], {220, 250}]
  • 2
    As an active CV user (and one who has frequently used MMA in replies there) I would be delighted to post the winning ad there. Or even rotate through the ads: every one of the contributions in this thread looks great to me :-). PS You might have enough rep here to ping anyone you like in chat using the "@@" construct--could be worth a try in the future. – whuber May 23 '12 at 15:29
  • @whuber I think rotating the ads is a great idea! I tried @@-ing you in the Mathematica chatroom a few hours ago, but you didn't respond: I think you didn't receive the notification. I think @@ is a moderator-only tool. – Szabolcs May 23 '12 at 20:43
  • @Szabolcs It is a moderator only feature – rm -rf May 23 '12 at 20:44
  • @Sz Yes, sorry about that--I didn't hear any pings. I thought it would be worth a try, since most moderator tools are available to people with your high reputation. – whuber May 23 '12 at 20:44
  • 1
    @Sz Is this what you had in mind? – whuber May 23 '12 at 20:53
  • @whuber Yes, exactly! – Szabolcs May 23 '12 at 20:57
  • It needs one more vote to get over the vote threshold - thanks @whuber! – Verbeia May 24 '12 at 2:10
  • @V Alas, to be acted on it needs to be posted in a successor thread: I mistakenly posted it in the thread for 2H 2011 rather than 1H 2012. So I had to migrate the ad and now voting needs to start all over again. Please visit meta.stats.stackexchange.com/a/1169 if you would like to vote. – whuber May 24 '12 at 13:58
5

As you said, if we are going to promote the site, we might need a preliminary logo.

I didn't post about this yet (I thought it was too soon---we just got out of private beta!), but my idea for a site logo was using a spikey:

enter image description here

We can have a spikey-design contest to create a special logo for this site only. Who can make the best looking one in Mathematica?

Why a custom spikey?

  • It is instantly recognizable as something related to Mathematica

  • Yet it will not be identical to any official Mathematica logo, so it will not be version specific and will not step on any trademarks

We have several people here who like to create art with Mathematica. I think there'll be a lot of interest!

The code for generating the version 4 logo is here, for version 5 it's here, and a Wolfram Blog entry about spikey making is here.

  • I would suggest we pick a colour that has not been used for an official spikey. Say green or a bluish purple. Or, as an alternative to a spikey, some other icosahedron based graphic. See my web site for a non-spikey alternative. – Verbeia Jan 27 '12 at 12:15
  • @Verbeia I agree, I was thinking about something as different as possible, while still preserving some vague resemblance to Mathematica. The image on your site also reminds of Mathematica a bit, even though it is completely different. – Szabolcs Jan 27 '12 at 12:34
  • Excellent idea. The logo search might deserve its own separate question though... – David Z Jan 27 '12 at 18:13
  • @David Yes, it should be a separate question. But from chat I got the impression most would like a different kind of logo, so let's wait with that. I just wanted to throw in the idea – Szabolcs Jan 27 '12 at 18:20
  • Designing a log should really become part of a post that starts suggesting designs for this site, as outlined here: The 7 Essential Questions of Every Beta – Robert Cartaino Jan 27 '12 at 21:36

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .