How can I easily copy Mathematica code for use with this site? (We have a palette for this!)

Question

I have recently posted a question asking how we could create a palette for copying code in the format originally suggested by Sjoerd and since adopted by several people:

D[x^2, x]

(* ==> 2 x *)

Range[50]

(*
==> {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, \
18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, \
35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50}
*)

This format makes it very clear what is input and what is output, and it also makes it very easy to copy the code back into a Mathematica notebook in a single go.

The question has since borne fruit, as it received two great answers. A palette based on these answers is in the answer below.

Note: the purpose of this palette is simply to make it easier to use this style for those who want to follow it. This site does not have any policy about a style for distinguishing inputs from outputs in posts.

Answer 1

Thanks to Albert Retey and Rolf Mertig now we have an easy way to copy code from Mathematica. The source for the code copy palette is below (note that the core code is written by Albert Retey, not me).

Evaluate it to create the palette, pop it out from the notebook, and save it for permanent use with the Palettes -> Install Palette... menu item. (When you do this, older versions of the same palette will be overwritten.)

The latest version will always be available in this post.

The palette copies code already indented (for pasting as a code block), with output cells commented out.

Please test this palette, evaluate its usability, and post suggestions, ideas, bug reports in the comments below.

---

PaletteNotebook[
  Tooltip[Button["Copy for MSE",
  If[MemberQ[Hold[{}, $Failed, NotebookRead[$Failed]],
        NotebookRead[SelectedNotebook[]]],

    Beep[],

    FrontEndTokenExecute[SelectedNotebook[], "CopySpecial", "InputText"];
    Map[
      CreateDocument[
        Cell[BoxData[#], "Code", 
             Evaluatable -> False, InitializationCell -> False,
             Background -> White, CellMargins -> 10], 
        DockedCells -> Cell[BoxData@ToBoxes@Button["Copy all", 
              SelectionMove[EvaluationNotebook[], All, Notebook]; 
              FrontEndTokenExecute[SelectedNotebook[], "Copy"]], 
            "DockedCell"], 
       WindowTitle -> "Code to copy (from " <> NotebookTools`NotebookName@SelectedNotebook[] <> ")",
       Saveable -> False] &, 

       Cases[NotebookGet@ClipboardNotebook[], 
         Cell[c_String, ___] :> "    " <> 
          StringReplace[
             StringJoin@Riffle[
              StringReplace[
               StringTrim@StringSplit[c, ("In" | "Out") ~~ "[" ~~ DigitCharacter .. ~~ "]"], 
               {StartOfString ~~ ":=" ~~ WhitespaceCharacter ~~ input__ :> input, 
                StartOfString ~~ "=" ~~ WhitespaceCharacter ~~ output__ :> 
                      If[StringFreeQ[output, "\n"],
                         "(* ==> " <> output <> " *)", 
                         "(*\n==> " <> output <> "\n*)"]
               }
              ], 
             "\n\n"],
          {"\n" -> "\n    ",
           "\[Pi]" -> "Pi", "\[ExponentialE]" -> "E", 
           "\[ImaginaryI]" | "\[ImaginaryJ]" -> "I", 
           "\[UndirectedEdge]" -> "<->",
           "\[Infinity]" -> "Infinity"}], Infinity]]
    ], Appearance -> "Palette"],
  "Copy formatted for use on Mathematica.SE", TooltipDelay -> Automatic],  
  WindowTitle -> "Code Copy", Saveable -> False]