Upload large amount of data more easily

Question

Lately I came across this question with a huge amount of data which I put on pastebin here under my account.

One can see that I've already put quite a few mathematica.stackexchange.com-related set of data on my Pastebin with various lengths to ease the reading of some questions.

So I was wondering if it was possible to have a mma.se account for the community? Or maybe something like the imgur-palette?

Of course, it would be possible to upload them as guests, without an account, but at least with an account it's possible to edit/delete more easily.

Answer 1

Lest we forget, there is also a built-in way in V10 to share expressions with other users, namely CloudPut with Permissions -> "Public" and CloudGet:

Answer 2

This is a proof-of-concept using Pastebin. It's a utility function that you can put in your init.m to always have available in case you need to upload a list (or another string).

How to install it

1. Create a user account at Pastebin.com.
2. Log in and copy your dev key from this page.
3. Go to this page and generate a user key.
4. Modify the function below with your own dev key and user key, and put the function where you want it (init.m for example.)

Function

Pastebin[expr_, OptionsPattern[{
    DevKey -> "<your dev key here>",
    UserKey -> "<your user key here>",
    PastePrivate -> "0",
    PasteName -> "",
    PasteExpireDate -> "N",
    }]] := With[{url = URLFetch[
     "http://pastebin.com/api/api_post.php",
     "Method" -> "POST",
     "Parameters" -> {
       "api_option" -> "paste",
       "api_dev_key" -> OptionValue[DevKey],
       "api_user_key" -> OptionValue[UserKey],
       "api_paste_private" -> OptionValue[PastePrivate],
       "api_paste_name" -> OptionValue[PasteName],
       "api_paste_expire_date" -> OptionValue[PasteExpireDate],
       "api_paste_code" -> expr
       }
     ]},
    CopyToClipboard[
     StandardForm[
      Defer[Import][
      "http://pastebin.com/raw.php?i=" <> StringReplace[url, "http://pastebin.com/" -> ""]]
      ]
   ];
  Hyperlink[url]
  ]

How to use it

The only required argument is the string you want to upload. If the upload is successful a link is returned to the frontend and the corresponding Import statement is copied to the clipboard.

Pastebin[ToString@Range[10], PasteName -> "Test", PasteExpireDate -> "1W"]
(* Out: http://pastebin.com/postID *)

The clipboard now holds Import["http://pastebin.com/raw.php?i=postID"].

There are are three options:

• PastePrivate 0 = public, 1 = unlisted and 2 = private
• PasteExpireDate N = Never, 10M = 10 Minutes, 1H = 1 Hour, 1D = 1 Day, 1W = 1 Week, 2W = 2 Weeks, 1M = 1 Month
• PasteName Each post can have a name.

Screencast

Answer 3

Not-so-large data can be QR-encoded in an image and uploaded to SE easily

dat = RandomInteger[9, {500, 3}];
BarcodeImage[Compress[dat], "QR"]

dat===Uncompress@BarcodeRecognize@Import["https://i.sstatic.net/aulnt.png"]
> True

Not very efficient, I would agree, but simple enough.

Answer 4

One needs to address two main issues first, before entertaining an answer

Permanence

The main issue is find a method that will remain available permanently.

Unfortunately, we've had a lot of users share files on dropbox and then delete them at their end when they got the answer :( – rm -rf

Minimalist policy

One should, in most cases, avoid large data or code, by providing a minimum working example, with code that generates simple synthetic data, if necessary. So try not to do this.

See also Q2145

Solutions

HTML imbedded

This Q&A takes advantage of the fact that Mathematica Stack Exchange accepts HTML in the questions, invalid HTML is ignored when formatting the question for display, but still be available when editing the question.

You can format your data and paste at the end of your question.

EncodeForQuestion[expr_List] := 
 CopyToClipboard[
  StringJoin["<data payload=\"", 
    URLEncode[ExportString[expr, "CSV"]], "\"/>"]]

and get the data back with the API

GetQuestionPlain[SEQuestionId_Integer] := Import[
   URLBuild[
    {"https://api.stackexchange.com", "2.2", "posts", ToString[SEQuestionId]}
    , {"site" -> "mathematica", "filter" -> "!SWK9z)LGKmEEgF5)yL"}]
   , "RawJSON"][["items", 1, "body_markdown"]]

Be aware of these safety considerations

Data on imgur image

QR answer before.

As described in this other answer.

Answer 5

Using DropBox

data = RandomInteger[9, {1000, 3}];

dropbox = ServiceConnect["Dropbox", "New"];
ServiceExecute[dropbox
  ,"DataUpload"
  , {
    "Path" -> "/MmaSE/datatest.txt"
  , "Data" ->Compress[data]
   }
 ];

Now share manually in the DropBox page get the URL and change the option "?dl=0" to "?dl=1"

data == Uncompress[
 Import["https://www.dropbox.com/s/tofsut7k90m90pi/datatest.txt?dl=1", "Text"]
 ]
(* True *)

Unfortunately dropbox["FileData", "Path" ->file] does not provide the sharing link.

Answer 6

paste.ee

https://paste.ee also offers permanent (never expire) paste with raw download.

pasteee[expr_, OptionsPattern[
   {
    "key" -> pasteekey (* Put your key string *)
    , "expire" -> "0"
    , "description" -> "Mma.SE"
    }]
  ] := Module[{
   import,
   id = URLFetch["https://paste.ee/api"
     , "Method" -> "POST"
     , "Parameters" ->
      {"key" -> OptionValue["key"]
       , "expire" -> OptionValue["expire"]
       , "description" -> OptionValue["description"]
       , "format" -> "simple"
       , "return" -> "id"
       , "paste" -> expr
       }]},
  import = StringJoin["Import[\"https://paste.ee/r/", id, "\"]"];
  CopyToClipboard@import;
  Echo[import, "Copied Clipboard: "];
  SystemOpen@StringJoin["https://paste.ee/p/", id];
  Row[{"Download file: ", URL[StringJoin["https://paste.ee/d/", id]]}]
  ]

Use

pasteee[
 "https://mathematica.meta.stackexchange.com/q/1351/10397"
 , "description" -> "Mma.meta.SE Q1351"
 ]